title	DADDR - test routine for DOMAIN JSYS

	search	macsym,monsym


start:	reset
	move p,[iowd pdlen,pdlist]

rloop:	move 1,prompt		;ask for host name
	psout

	move 1,[	point	7,inbuf	]
	movei 2,inbufl
	move 3,prompt
	rdtty
	 erjmp rloop

	move 1,[	point	7,inbuf	]
zloop:	ildb 2,1		;turn CR into null in inbuf
	caie 2,15
	 jrst zloop
	sub 2,2
	dpb 2,1

	movei 1,3		;call gtdom% to get address of host
	move 2,[	point	7,inbuf]
	gtdom%
	 jrst errorp		;or find error

	movem 1,rett1
	movem 2,rett2
	movem 3,rett3
	movem 4,rett4

	txne 4,hs%nck		;print nickname if bit set
	 jrst [	hrroi 1,[asciz /nickname /]
		psout
		jrst .+1]

	call pina		;print out internet address
	hrroi 1,[asciz / /]
	psout

;	now go do reverse transformation
	movei 1,2	;number to name
	move 2,[	point 7,outbuf]
	move 3,rett3
	gtdom%
	 jrst errorp

	move 1,[	point 7,outbuf]	;and print name obtained by inverse
	psout
	hrroi 1,[asciz /
/]
	psout
	jrst rloop

	inbufl=400
inbuf:	block	inbufl/5
outbuf:	block	inbufl/5

rett1:	block	1
rett2:	block	2
rett3:	block	3
rett4:	block	4

prompt:	point 7,[ asciz /Enter Host Name:/]

errorp:	push p,1
	hrroi 1,[ asciz /Error /]
	psout
	pop p,2
	hrrz 2,2
	movx 1,.priou
	movei 3,10
	nout
	 nop
	hrroi 1,[asciz / returned
/]
	psout
	jrst rloop

	pdlen==200
pdlist:	block	pdlen

;
;	PINA prints the internet address in ac3 on the primary
;	output
;

pina:	move 4,3
	move 5,[ point 8,4,3]
	pushj p,outoct
	pushj p,[outdot:	hrroi 1,[ asciz /./]
				psout
		 outoct:	ildb 2,5
				movx 1,.priou
				movei 3,^d10
				nout
				 nop
				popj p,	]
	pushj p,outdot
	pushj p,outdot
	hrroi 1,[asciz / /]
	psout
	ret
	end	start